스프레드시트 filter 함수 or 조건 - seupeuledeusiteu filter hamsu or jogeon

FILTER 함수 목차 바로가기

1. 예제파일 다운로드
2. FILTER 함수 실전예제 영상강의
3. 오피스 365 사용자가 아니라면? xFILTER 추가기능 알아보기
4. FILTER 함수 기초 사용법
5. 다중조건 필터링 - AND조건
6. 다중조건 필터링 빈칸인식 문제해결
7. 다중조건 필터링 - OR조건
8. 부분일치 필터링 (특정문자 포함 조건)
9. 필터링 된 범위 자동 정렬하기
10. FILTER 함수로 출력된 범위만 테두리 칠하는 방법
11. 그외 참고사항

함수 요약

엑셀 FILTER 함수는 입력한 조건을 바탕으로 데이터를 필터링하는 함수입니다.

함수 구문

= FILTER ( 범위, 조건, [결과없음반환값] )

인수 알아보기엑셀 FILTER 함수 사용예제

인수	설명
범위	필터링 할 전체 범위 또는 배열입니다.
조건	범위에서 필터링을 적용할 조건입니다. 조건의 넓이 또는 높이는 범위와와 반드시 동일해야 합니다.
결과없음반환값 [선택인수]	FILTER 함수의 결과로 아무것도 반환되지 않을경우 출력할 값입니다. 기본값으로 #CALC! 오류를 반환합니다.

호환성

운영체제	호환성
Windows 버전	엑셀 2021 또는 M365 사용자에게만 제공됩니다.
Mac 버전	엑셀 2021 또는 Mac용 M365 사용자에게만 제공됩니다.

예제파일 다운로드

오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.

관련 기초함수

엑셀 FILTER 함수 사용예제

1. FILTER 함수 기본 사용법 (셀을 참조하여 동적 필터링하기)

=FILTER(범위, (조건범위=조건), "결과없음" )

조건범위에서 조건과 일치하는 값을 찾아 필터링합니다. 조건 연산자로 등호(=) 이외에도 크게(>), 작게(<) 등을 이용할 수 있습니다.

예제파일에 사용된 공식

=FILTER(B9:D18,(B9:B18=G9),"결과없음")

FILTER 함수로 부서에서 A팀을 필터링합니다.2. FILTER 함수 다중조건 필터링 (AND 조건 필터링)

=FILTER(범위, (조건범위1=조건)*(조건범위2=조건2), "결과없음" )

각각의 조건범위에서 해당 조건을 모두 일치하는 값을 찾아 필터링합니다. 즉, 두개의 조건을 '모두 만족'할 경우의 값을 불러옵니다. 예를들어, A부서 '이고 동시에' 판매실적이 4500이상일때의 값을 출력합니다.

AND조건 필터링은 각각의 조건을 '곱셈'으로 계산합니다.

예제파일에 사용된 공식

=FILTER(B9:D18,(B9:B18=G9)*(D9:D18>G10),"결과없음")

부서와 판매실적 조건을 모두 만족하는 값을 필터링합니다.3. 다중조건 필터링 빈칸인식 문제해결

=FILTER(범위, IF(조건1="",조건범위1=조건범위1,(조건범위1=조건1))*IF(조건2="",조건범위2=조건범위2,(조건범위2=조건2)), "결과없음" )

AND 조건의 다중조건 필터링 시, 조건 중 하나라도 빈칸이 될 경우 모든 결과값으로 FALSE가 반환되어 다른 조건에 상관없이 항상 '결과없음'이 출력되는 문제가 발생합니다.

FILTER 함수 다중조건 사용시, 조건중 하나가 빈칸일 경우 모든 결과가 FALSE로 반환됩니다.

빈칸인식 문제는 조건안에 IF 함수를 사용하여 간단히 문제를 해결할 수 있습니다.

예제파일에 사용된 공식

=FILTER(B9:D18,IF(G9="",B9:B18=B9:B18,(B9:B18=G9))*(D9:D18>G10),"결과없음")

IF 함수를 사용하여 FILTER 함수 다중조건 빈칸인식 문제를 해결합니다.4. FILTER 함수 다중조건 필터링 (OR 조건 필터링)

=FILTER(범위, (조건범위1=조건)+(조건범위2=조건2), "결과없음" )

OR조건으로 다중조건 필터링을 적용할 수도 있습니다. 예를들어, A부서 '이거나 또는' B부서 일 경우의 조건을 모두 필터링하게 됩니다.

OR 조건 필터링은 여러개의 조건을 '덧셈'으로 계산합니다.

예제파일에 사용된 공식

=FILTER(B9:D18,(B9:B18=G9)+(B9:B18=G10),"결과없음")

여러 조건을 덥셈으로 입력하면 OR 조건 필터링이 됩니다.5. 부분일치(특정문자 포함) 조건으로 필터링

=FILTER(범위, ISNUMBER(SEARCH(조건,조건범위)), "결과없음" )

예를들어, 직원명에서 '임'씨로 시작하는 사람 또는 '서현'이라는 이름을 가진 사람 등 '특정 문자를 포함하는 값'을 모두 필터링 하려면 어떻게 해야할까요?

바로 ISNUMBER-SEARCH 함수 부분일치 공식을 FILTER 함수의 조건으로 사용하면 간단히 해결됩니다.

예제파일에 사용된 공식

=FILTER(B9:D18,ISNUMBER(SEARCH(G9,C9:C18)),"결과없음")

부분일치검색 공식을 사용하여 특정문자를 포함하는 값을 필터링합니다.6. 반환값을 원하는 기준으로 정렬하기

=SORT(FILTER(범위, (조건범위=조건), "결과없음"), 열번호, 정렬방향)

SORT 함수를 같이 응용하면, FILTER 함수로 출력된 값을 원하는 기준에 맞춰 정렬할 수 있습니다. 예를들어, A부서로 필터링된 범위를 '판매실적'을 기준으로 '오름차순'으로 정렬하여 값을 출력하게 됩니다.

예제파일에 사용된 공식

=SORT(FILTER(B9:D18,(B9:B18=G9),"결과없음"),3,1)

SORT 함수를 응용하여 FILTER 함수 결과값을 원하는 기준으로 필터링 할 수도 있습니다.7. 필터함수로 출력된 범위만 테두리 칠하기 (조건부서식 응용)

=$A1<>""
'// 알파벳 앞에만 $ 표시를 붙이는 것에 주의합니다. (열절대참조)

FILTER 함수는 동적배열함수로 검색조건에 따라 매번 출력범위가 변합니다. 이럴경우, 출력된 범위에만 테두리를 자동으로 입혀주려면 어떻게 해야 할까요?

조건부서식을 응용하여 아주 간단하게 해결할 수 있습니다.

1. FILTER 함수로 출력될 예상범위를 넉넉하게 선택합니다.
   FILTER 함수로 출력될 범위를 넉넉하게 선택합니다.
2. '홈' - '조건부서식' - '새 규칙'으로 이동합니다.
   '조건부서식' - '새규칙'으로 이동합니다.
3. '수식을 사용하여 서식을 지정할 셀 결정'을 선택한 뒤, 아래 수식을 입력합니다.

   $기준셀(열 절대참조)<>""

   수식을 입력합니다. '열절대참조'로 셀주소를 입력하는 것에 주의합니다.
4. [서식]을 클릭한 뒤, '테두리'에서 윤곽선을 선택합니다.
   '서식' - '테두리' 에서 '윤곽선'을 선택합니다.
5. FILTER 함수로 값이 출력될 때마다, 출력된 범위에만 테두리가 칠해집니다.
   FILTER 함수로 범위가 출력될 때마다, 값이 입력된 범위에만 테두리가 칠해집니다.

함수 사용시 참고사항

• 엑셀 FILTER 함수는 가로 또는 세로방향으로 모두 필터링이 가능합니다.
• 조건으로 입력되는 값의 높이 또는 넓이는 첫번째 인수인 '범위'와 반드시 동일해야 합니다. 그렇지 않을경우 FILTER 함수는 #VALUE!오류를 반환합니다.
• 만약 FILTER 함수로 반환되는 결과값이 없고 [결과없음반환값]이 입력되지 않으면, FILTER 함수는 #CALC!오류를 반환합니다.
• 만약 조건으로 입력된 수식이 잘못되어 오류를 반환할 경우(#N/A!. #VALUE! 등), FILTER 함수 또한 항상 오류를 반환하게 됩니다.
• FILTER 함수가 '다른 통합문서'를 참조하여 작성될 경우, 해당 통합문서는 반드시 열려있어야 합니다. 그렇지 않을 경우, FILTER 함수는 #REF!오류를 반환합니다.

링크: MS 홈페이지 FILTER 함수 사용법